home *** CD-ROM | disk | FTP | other *** search
/ Amiga Plus 1998 #4 / Amiga Plus CD - 1998 - No. 4.iso / pd / tools / wbstars2.0 / source / cback.a next >
Text File  |  1997-05-25  |  14KB  |  536 lines
  1. *
  2. * C initial startup procedure under AmigaDOS
  3. * 
  4.  
  5.         INCLUDE "exec/types.i"
  6.         INCLUDE "exec/alerts.i"
  7.         INCLUDE "exec/nodes.i"
  8.         INCLUDE "exec/lists.i"
  9.         INCLUDE "exec/ports.i"
  10.         INCLUDE "exec/libraries.i"
  11.         INCLUDE "exec/tasks.i"
  12.         INCLUDE "exec/memory.i"
  13.         INCLUDE "exec/execbase.i"
  14.         INCLUDE "libraries/dos.i"
  15.         INCLUDE "libraries/dosextens.i"
  16. FUNCDEF         MACRO   * function
  17. _LVO\1          EQU     FUNC_CNT
  18. FUNC_CNT        SET     FUNC_CNT-6
  19.                 ENDM
  20.  
  21. FUNC_CNT        SET     LIB_NONSTD
  22.  
  23.         INCLUDE "exec/exec_lib.i"
  24.         INCLUDE "libraries/dos_lib.i"
  25.         INCLUDE "workbench/startup.i"
  26.  
  27. AbsExecBase EQU 4
  28.  
  29. TINY    EQU     0
  30. callsys macro
  31.         CALLLIB _LVO\1
  32.         endm
  33.         
  34.     xdef    XCEXIT            ; exit(code) is standard way to leave C.
  35.     xdef     @XCEXIT
  36.     
  37.     xref    LinkerDB        ; linker defined base value
  38.     xref    _BSSBAS        ; linker defined base of BSS
  39.     xref    _BSSLEN        ; linker defined length of BSS
  40.  
  41.     xref    _main            ; Name of C program to start with.
  42.         xref    __fpinit                * initialize floating point
  43.         xref    __fpterm                * terminate floating point
  44.  
  45. *    library references
  46.  
  47.     csect    _NOMERGE,0,0,0,4
  48.     xref    MemCleanup
  49.     xref    FindTask
  50.  
  51. start:
  52.         movem.l d1-d6/a0-a6,-(a7)
  53. REGSIZE EQU     (6+7)*4
  54.         lea     REGSIZE(a7),A5         * determine old stack pointer
  55.         move.l  a0,a2                  * save command pointer
  56.         move.l  d0,d2                  * and command length
  57.         lea     LinkerDB,a4            * load base register
  58.  
  59.         move.l  AbsExecBase.W,a6
  60.         move.l  a6,SysBase(A4)
  61.         move.l  a7,_StackPtr(A4)       * Save stack ptr
  62.         clr.l   WBenchMsg(A4)
  63.  
  64. *------    Clear out our BSS section
  65.         lea     _BSSBAS,a3             * get base of BSS
  66.         moveq   #0,d1
  67.         move.l  #_BSSLEN,d0            * get length of BSS in longwords
  68.         bra.s   clr_lp                 * and clear for length given
  69. clr_bss move.l  d1,(a3)+
  70. clr_lp  dbf     d0,clr_bss
  71.  
  72. *------ get the address of our task
  73.     move.l    ThisTask(a6),A3
  74.  
  75. *-----  clear any pending signals
  76.     moveq    #0,d0
  77.     move.l    #$00003000,d1
  78.     callsys    SetSignal
  79.  
  80. *------ are we running as a son of Workbench?
  81.     move.l    pr_CurrentDir(A3),curdir(A4)
  82.     tst.l    pr_CLI(A3)
  83.     beq    fromWorkbench
  84.  
  85. *=======================================================================
  86. *====== CLI Startup Code ===============================================
  87. *=======================================================================
  88.  
  89. fromCLI:
  90. *------    attempt to open DOS library:
  91.     bsr.w    openDOS
  92.  
  93. *------ Duplicate the current directory for the called process
  94.     move.l    curdir(A4),D1
  95.     move.l    DOSBase(A4),A6
  96.         callsys DupLock
  97.         move.l  D0,curdir(A4)
  98.  
  99. *------ find command name:
  100.     move.l    pr_CLI(A3),a0
  101.     add.l   a0,a0            ; bcpl pointer conversion
  102.     add.l   a0,a0
  103.     move.l    cli_CommandName(a0),a1
  104.     add.l   a1,a1            ; bcpl pointer conversion
  105.     add.l   a1,a1
  106.  
  107. *------    collect parameters:
  108.     move.l    d2,d0        ; get command line length
  109.     moveq.l    #0,d1
  110.     move.b    (a1)+,d1
  111.         move.l  A1,D4                   ;save our pointer
  112.     move.l    d1,d3
  113.     add.l    d1,d1            ; double length since we copy it twice
  114.     add.l    d1,d0            ; add length of command name
  115.     addq.l    #5,d0            ; allow for space after command    
  116.     addq.l    #4,d0            ; As well as for the roundup
  117. *                          ; changed from 5 to 9 for quotes
  118. *                                         
  119. *------    We have the length of the command string to be copied.
  120. *------    Allocate space for it.
  121. *------    Round up to the nearest 4 bytes
  122.     lsl.l    #2,d0
  123.     add.l    memsize(A4),d0
  124.     move.l    d0,memsize(A4)
  125.  
  126. ************************************************************************
  127. ************************************************************************
  128. ******** Allocate and copy over the code to do the magic stuff *********
  129. ************************************************************************
  130. ************************************************************************
  131.  
  132.     lea    memlist(A4),A0
  133.         move.l  AbsExecBase.W,a6
  134.     callsys    AllocEntry        ;get a place to put the code
  135. *    btst.l    #31,d0            ;did we get the memory we asked for?
  136. *    beq    cliexit            ;no, can't do anything then
  137.     move.l    D0,A1
  138.     move.l    D0,-(A7)        ;remember the chunk we allocated
  139.  
  140. *------ Now we copy the code over
  141.     movea.l    ML_SIZE+ME_ADDR(A1),A1    ;locate our allocated block
  142.  
  143. *------    Copy over the command line to the allocated area
  144.     lea    commandbuf-copybeg(A1),A3
  145.  
  146. *------    At this point, we have:
  147. *        A0 - Work pointer
  148. *        A1 - Pointer to Allocated memory block
  149. *        A2 - Pointer to program name
  150. *        A3 - Pointer to target buffer
  151. *        A3 - Pointer to our process structure
  152. *        D0 - Work register
  153. *        D1 - Work register
  154. *        D2 - length of command name
  155. *        D3 - length of program name
  156. *               D4 - Pointer to program name
  157.  
  158.     movea.l    D4,A0            ; Load program name
  159.     move.l    D3,D0            ;      and length
  160.         move.b  #'"',(a3)+
  161.     bra.s    cpy1
  162. cpycmd:    move.b    (A0)+,(A3)+        ; copy over the command name
  163. cpy1:    dbf    d0,cpycmd
  164.         move.b  #'"',(a3)+
  165.     move.b    #' ',(A3)+        ; add the space delimiter
  166.  
  167.     move.l    A2,A0            ; Load command text
  168.     move.l    D2,D0            ;      and length
  169.     bra.s    cpy2
  170. cpylin:    move.b    (A0)+,(A3)+
  171. cpy2:    dbf    d0,cpylin
  172.     clr.b    (A3)+
  173.  
  174. *------    Now copy over the program name
  175.     move.l    A3,_ProgramName(A4)
  176.     move.l    D4,A0
  177.     move.l    D3,D0
  178.     bra.s    cpy3
  179. cpypgm:    move.b    (A0)+,(A3)+
  180. cpy3:    dbf    D0,cpypgm
  181.     clr.b    (A3)            ;don't forget trailing null on name
  182.  
  183. *------ First we want to put it into our seglist
  184.     lea    segexit-copybeg(A1),A2
  185.     move.l    A2,XCEXIT+2(A4)        ;patch the jump instruction
  186.     lea    start-4(PC),A2
  187.    
  188. *    Now we have:    A1 to our new fake segment
  189. *            A2 to the start of the real seglist
  190.     move.l    #(copyend-copybeg)/4,(A1)+
  191.     move.l    A1,D3
  192.     lsr.l    #2,D3            ;convert it to a bptr to the list
  193.     move.l    (A2),(A1)+        ;save our next segment pointer
  194.     clr.l    (A2)            ;and kill it from the chain
  195. *------ We have the seglist
  196.  
  197.     lea    AutoLoader(PC),A2
  198.     move.l    #(copyend-AutoLoader)-1,D0
  199. copyit    move.b    (A2)+,(A1)+
  200.     dbf    d0,copyit
  201.  
  202. *------    See if they want to do some I/O
  203.     tst.l    _BackGroundIO(A4)
  204.     beq    noio
  205.         lea     current_window(A4),A0
  206.         move.l  A0,D1
  207.     move.l    #1005,D2
  208.     move.l    DOSBase(A4),A6
  209.     callsys    Open
  210.     move.l    d0,_Backstdout(A4)
  211. noio:
  212.     move.l    AbsExecBase.w,A6
  213.  
  214. *------ If under 2.0 Flush cache
  215.    
  216.    moveq    #24,d0
  217.    cmp.w    $14(a6),d0
  218.    bcs.b    nocache
  219.    moveq    #-1,d0
  220.    callsys  CacheClearU
  221.  
  222. nocache:   
  223.     callsys    Forbid
  224.  
  225. *------ Attach the task to do the dirty work
  226.     move.l    _procname(A4),D1    ; Name of task to start
  227.     move.l    _priority(A4),D2    ; Priority of background task
  228.     move.l    _stack(A4),D4        ; Stack size of created task
  229.  
  230.     move.l    DOSBase(A4),A6
  231.     callsys    CreateProc
  232.     move.l    A6,A3        ; restore dosbase to close it
  233.     tst.l    D0
  234.     bne    ok
  235.  
  236. *------ Serious problems.  For some reason the CreateProc failed.
  237. *------ We need to free the AlocEntry memory and go home
  238.     move.l    (A7)+,A2
  239.     movea.l    ML_SIZE+ME_ADDR(A2),A1    ;locate our allocated block
  240. *------ Also must get rid of current directory
  241.         move.l  curdir(A4),D1
  242.         callsys UnLock
  243.  
  244.         move.l  A2,A0
  245.     move.l    AbsExecBase.w,A6
  246.     callsys    FreeEntry
  247.     move.l    #104,D0
  248.     bra    cliexit
  249.  
  250. ok:
  251. *------ The task started ok, attach the memory we allocated to
  252. *------    its task control block
  253.     move.l    D0,A2
  254.  
  255.     move.l    (a7)+,A1        ;locate the memory we allocated
  256.     lea    -pr_MsgPort(A2),A2
  257.     lea    TC_MEMENTRY(A2),A0
  258.  
  259.  
  260. *    ADDTAIL
  261.     LEA    LH_TAIL(A0),A0
  262.     MOVE.L    LN_PRED(A0),D0
  263.     MOVE.L    A1,LN_PRED(A0)
  264.     MOVE.L    A0,(A1)
  265.     MOVE.L    D0,LN_PRED(A1)
  266.     MOVE.L    D0,A0
  267.     MOVE.L    A1,(A0)
  268.  
  269.     move.l    #0,D0
  270.  
  271. cliexit:
  272.     move.l    AbsExecBase.w,A6
  273.     callsys    Permit
  274.     move.l    A3,A1
  275.     move.l    AbsExecBase.w,A6
  276.     callsys    CloseLibrary
  277.     movem.l    (a7)+,d1-d6/a0-a6
  278.     rts
  279.  
  280. *=======================================================================
  281. *====== Workbench Startup Code =========================================
  282. *=======================================================================
  283.  
  284. fromWorkbench:
  285.  
  286.     move.l    TC_SPLOWER(A3),_base(A4)    ; set base of stack
  287.         add.l   #128,_base(A4)          ;allow for parms overflow
  288. *------ open the DOS library:
  289.     bsr.w    openDOS
  290.  
  291.     lea    xcexit(PC),A2
  292.     move.l    A2,XCEXIT+2(A4)        ;patch the jump instruction
  293.     
  294. *------ we are now set up.  wait for a message from our starter
  295.     bsr.w    waitmsg
  296.     move.l    d0,WBenchMsg(A4)
  297.     move.l    d0,-(SP)
  298. *
  299.     move.l    d0,a2            ; get first argument
  300.     move.l    sm_ArgList(a2),d0
  301.     beq.s    do_cons
  302.     move.l    DOSBase(A4),a6
  303.     move.l    d0,a0
  304.     move.l    wa_Lock(a0),d1
  305.         callsys DupLock
  306.     move.l    d0,curdir(A4)
  307.     move.l    d0,d1
  308.     callsys    CurrentDir
  309. do_cons:
  310.     move.l    sm_ToolWindow(a2),d1    ; get the window argument
  311.     beq.s    do_main
  312.     move.l    #MODE_OLDFILE,d2
  313.     callsys    Open
  314.     move.l    d0,stdin(A4)
  315.     beq.s    do_main
  316.     lsl.l    #2,d0
  317.     move.l    d0,a0
  318.     move.l    fh_Type(a0),pr_ConsoleTask(A3)
  319. do_main:
  320.     move.l    WBenchMsg(A4),a0        ; get address of workbench message
  321.     move.l    a0,-(a7)        ; push argv
  322.     pea    NULL(A4)        ; push argc
  323.     move.l    sm_ArgList(a0),a0    ; get address of arguments
  324.     move.l    wa_Name(a0),_ProgramName(A4)    ; get name of program
  325. *------ For startup from workbench, there is no reason to go through
  326. *------ The fancy stuff to make the startup work.  Just run the
  327. *------ Code directly
  328.     jsr    __fpinit(PC)
  329.     jsr    _main
  330.     moveq.l    #0,d0
  331.     bra.w    exit2
  332.     
  333.  
  334. ************************************************************************
  335. ************************************************************************
  336. *************                                              *************
  337. ************* Start of code that is copied to fake segment *************
  338. *************                                              *************
  339. ************************************************************************
  340. ************************************************************************
  341.  
  342. copybeg:
  343.     DC.L    (copyend-copybeg)/4
  344. next:    DC.L    0
  345. AutoLoader:
  346.     move.l    a7,d0
  347.     movem.l    d1-d6/a0-a6,-(a7)
  348.     move.l    d0,a5
  349.     move.l    AbsExecBase.w,a6
  350.     lea    LinkerDB,A4        ; load base register
  351.     move.l    a7,_StackPtr(A4)
  352.  
  353.     bsr.w    openDOS
  354.     suba.l    a1,a1
  355.  
  356.     suba.l    a1,a1
  357.     callsys    FindTask
  358.     move.l    d0,A3
  359.  
  360.     move.l    TC_SPLOWER(A3),_base(A4)    ; set base of stack
  361.         add.l   #128,_base(A4)          ;allow for parms overflow
  362.  
  363.     move.l    pr_SegList(A3),a0    ;locate the segment list
  364.     add.l    A0,A0
  365.     add.l    A0,A0            ;and convert to an APTR
  366.     move.l    12(A0),A1        ;so we can access the segments
  367.     add.l    A1,A1
  368.     add.l    A1,A1
  369.  
  370.     move.l    (A1),seglist(A4)    ;save the remainder for later
  371.     move.l    (A1),12(A0)        ;cut off our segment
  372.  
  373.         move.l  curdir(A4),D1
  374.     move.l    DOSBase(A4),a6
  375.         callsys CurrentDir
  376.  
  377.     pea    commandbuf(PC)
  378.         jsr     __fpinit
  379.     jsr    _main                ; call C entrypoint
  380.     addq    #4,A7
  381.  
  382.  
  383. *------ Unlock the directory we set up for them
  384. segexit:
  385.     move.l    DOSBase(A4),a6
  386.         move.l  curdir(A4),D1
  387.         callsys UnLock
  388.  
  389.     moveq.l    #0,d0            ; set successful status
  390. xcexit:
  391. exit2:
  392.     IFEQ    TINY
  393.     move.l    _ONEXIT(A4),d0        ; exit trap function?
  394.     beq.s    exit3
  395.     move.l    d0,a0
  396.     jsr    (a0)
  397.     ENDC
  398.  
  399. exit3    jsr    MemCleanup        ; cleanup leftover memory alloc.
  400.  
  401.     jsr    __fpterm
  402.  
  403. done_1c:
  404. *------ if we ran from CLI, skip workbench cleanup:
  405.     tst.l    WBenchMsg(A4)
  406.     beq.s    exitToDOS
  407.     move.l    DOSBase(A4),a6
  408.     move.l    stdin(A4),d1
  409.     beq.s    done_4
  410.     callsys    Close
  411. done_4:
  412.  
  413. *------ return the startup message to our parent
  414. *    we forbid so workbench can't UnLoadSeg() us
  415. *    before we are done:
  416.         move.l  curdir(a4),d1
  417.         beq.s   done_5
  418.         callsys UnLock
  419.  
  420. done_5:
  421.     move.l    AbsExecBase.w,A6
  422.     callsys    Forbid
  423.     move.l    WBenchMsg(A4),a1
  424.     callsys    ReplyMsg
  425.  
  426. *------ this rts sends us back to DOS:
  427. exitToDOS:
  428.         movea.l _StackPtr(a4),a3        ; Put old stack pointer somewhere safe.
  429.  
  430. *------    They are done so unload them
  431.     move.l    seglist(A4),D1
  432.     move.l    DOSBase(A4),a6
  433.     callsys    UnLoadSeg
  434.  
  435.         move.l  a6,a1
  436.     move.l    AbsExecBase.w,a6
  437.     callsys    CloseLibrary        ; close Dos library
  438.  
  439.  
  440.     movea.l  a3,SP            ; restore stack ptr
  441.     movem.l    (a7)+,d1-d6/a0-a6
  442.     rts
  443.  
  444. *-----------------------------------------------------------------------
  445. *  Open the DOS library:
  446.  
  447. openDOS
  448.         lea    DOSName(A4),A1
  449.         moveq.l    #0,D0
  450.         callsys    OpenLibrary
  451.         move.l    D0,DOSBase(A4)
  452.         beq    noDOS
  453.         rts
  454. *-----------------------------------------------------------------------
  455. noDOS:
  456.         moveq.l    #100,d0
  457.         bra    exit2
  458.  
  459. copyend:
  460. commandbuf:
  461.  
  462. ************************************************************************
  463. ************************************************************************
  464. **************                                            **************
  465. ************** End of code that is copied to fake segment **************
  466. **************                                            **************
  467. ************************************************************************
  468. ************************************************************************
  469.  
  470. *-----------------------------------------------------------------------
  471. * This routine gets the message that workbench will send to us
  472. * called with task id in A3
  473.  
  474. waitmsg:
  475.         lea    pr_MsgPort(A3),a0      ; our process base
  476.         callsys    WaitPort
  477.         lea    pr_MsgPort(A3),a0      ; our process base
  478.         callsys    GetMsg
  479.         rts
  480.  
  481.     csect    __MERGED,1,0,0,4
  482.  
  483. *------    These externals control the task that is started
  484.     xref    _BackGroundIO        ; flag to indicate background task
  485. *                    ; wants to do I/O
  486.     xref    _stack            ; stack space for created task
  487.     xref    _procname        ; name of process to be created
  488.     xref    _priority        ; priority to create process at
  489.  
  490.     xref    DOSBase
  491.     xref    MathBase
  492.     xref    MathTransBase
  493. *
  494.     xdef    NULL,SysBase,WBenchMsg
  495.     xdef    curdir,_mbase,_mnext,_msize,_tsize
  496.     xdef    _oserr,_OSERR,_FPERR,_SIGFPE,_ONERR,_ONEXIT,_ONBREAK
  497.     xdef    _SIGINT,_Backstdout
  498.     xdef    _ProgramName,_StackPtr,_base
  499. *
  500. *        cnop    0,4
  501. memlist    ds.b    LN_SIZE
  502.         dc.w    1
  503.         dc.l    MEMF_PUBLIC
  504. memsize    dc.l    copyend-copybeg
  505.  
  506. XCEXIT    
  507. @XCEXIT        dc.w    $4ef9
  508.         dc.l    0
  509. seglist        dc.l    0
  510. NULL        dc.l    0        ;
  511. _base        dc.l    0        ; base of stack
  512. _mbase        dc.l    0        ; base of memory pool
  513. _mnext        dc.l    0        ; next available memory location
  514. _msize        dc.l    0        ; size of memory pool
  515. _tsize        dc.l    0        ; total size?
  516. _oserr        equ    *
  517. _OSERR        dc.l    0
  518. _FPERR        dc.l    0
  519. _SIGFPE        dc.l    0
  520. _SIGINT        dc.l    0
  521. _ONERR        dc.l    0
  522. _ONEXIT        dc.l    0
  523. _ONBREAK    dc.l    0
  524. curdir        dc.l    0
  525. SysBase        dc.l    0
  526. WBenchMsg    dc.l    0
  527. _StackPtr    dc.l    0
  528. dosCmdLen    dc.l    0
  529. dosCmdBuf    dc.l    0
  530. stdin        dc.l    0
  531. _Backstdout    dc.l    0        ;filehandle for I/O
  532. _ProgramName    dc.l    0
  533. DOSName     dc.b    'dos.library',0
  534. current_window    dc.b    '*',0
  535.         END
  536.